Appendix 1: A step-by-step description of opening the IISTC database

§ 16 The following discussion assumes that the user has the IISTC, Microsoft Windows, and Microsoft Office installed on his or her computer. While the IISTC runs only under Windows, similar results should be achievable with any database software.

1. Select all records in the IISTC. First, enter a search on the Search screen that returns all 28,360 records, such as searching for i* in the ISTC Number field. On the List Display screen, click on Select All. Once this choice has been confirmed, the computer may become unusable for an hour or more until the operation has completed.

2. After all records have been selected, click on Export, which is also on the List Display screen. This may also require considerable time before the dialogue box appears. Do not change the export range, but do change the export format to plain text by clicking on the button marked Using Rich Text Format (RTF); once you click on it, the title will change to read Using Plain Text (TXT), which is the desired format. Click on the button marked Export, then select a location for the exported file and give it a name. The examples here assume a filename of istc.txt. The export process may take many hours and tie up all the resources of the computer during that time. The resulting file will be over 22 megabytes in size.

3. The various fields in the IISTC can now be turned into tab-delimited tables one at a time using Perl scripts such as that found in appendix 2 and above. If the script is named title.pl, the output can be redirected to create a file named title.txt:

   perl title.pl > title.txt
   

   Otherwise the output will appear on screen. Scripts virtually identical to that found in appendix 2 can be used to create a series of files, each a tab-delimited table containing an ISTC number in one column and one additional field in the other.

4. These tables can now be imported one at a time into a database application. Using Microsoft Access, create a new database file, then open the text files one at a time using the File > Get External Data > Import function. Specify that the file is delimited, and that tabs separate the fields, and that it should be opened in a new table. Import the first field as indexed (no duplicates) and give it an appropriate title, so that the ISTC number can serve as the index of the imported database as well; the next stage of the import process will let you choose the ISTC number as the primary key for the database.

   Because some title records are longer than the 255-character limit that Access imposes on text fields, these records will be truncated and an error message will appear. Import the titles as a second table in the same way, but with the title field as a memo data type. The truncated titles can be used when sorting is necessary, while the full memo field will be available when the complete titles are needed, so both are useful.

   Import the rest of the text files in the same way, choosing appropriate titles for each table and an appropriate data type for each field. Maintain consistency in the naming of fields.

5. The tables can now be joined one at a time into one large flat-file database table, which can simplify later searches. Select the title table, because it contains all 28,360 records, and, for example, the authors table, which only contains 20,933. Create a query by selecting these two tables; the identical ISTC Number fields are already automatically joined. Right click on the link between the two tables, examine the join properties, and click on the third option: we need all the records from the title table as well as the corresponding records in author. Under the Query menu, select Make-Table Query and choose a name, such as istc2. Running the query will create a new table that includes all the ISTC numbers and titles for all records as well as the author for works that have one. Repeating this process with the newly created table and the table containing the next field to be imported will eventually result in a large table with all of the fields readily accessible in the ISTC database. The table should have 28,360 records after every step.

6. Some of the most useful information in the IISTC requires further analysis of its fields using more Perl scripts. A script to analyze the imprint field is found in appendix 3, while a script to provide a copy count is found in appendix 4. Each of these Perl scripts will create new tab-delimited tables that can be imported into the database by following steps 4 and 5 above.

7. Because the IISTC's Printing Regions function assigns some incunables to more than one region, this information cannot be imported into the same table. If this information is required, the relevant records would have to be exported from the IISTC separately, the ISTC Numbers extracted, and a new table created that does not use the ISTC Number as an index. One can then limit one's searches according to the IISTC's printing regions by searching out only those records in the larger table for which an ISTC number in the regions table is associated with the desired region.

§ 17 This is by no means the only possible approach towards creating a database from the IISTC records, or even one that is particularly faithful to the ideal of standards compliance. While Microsoft Access has a large install base, it is quite expensive; open-source and standards-compliant database solutions such as MySQL exist, but none yet matches the ease of use of Access. A monolithic flat file may not be the best database for all circumstances. In addition, some questions are still best handled by recourse to further script writing, particularly if further text manipulation is required, such as numerically sorting entries in the bibliographic standard works.

Appendix 2: A Perl script for extracting fields from the istc.txt file

§ 18 The comment lines, which begin with the pound sign, explain the function of each line of code.

$batch="istc.txt";
# Define the name of file to search
open BATCH, $batch or die "Cannot open $batch for read:$!";
# Open the file, or close with an
# error if it doesn't exist
while (<BATCH>) {
  # As long as there are lines
  # in the file left to search...
  if (/^Title:\t(.*?)$/) {
  # ...look for the pattern
  # "Title:<tab character><anything
  # else>
  # at the beginning of a line
    $match = $1;
    # Save "anything else"...
    $hit=1;
    # ...and set a flag that
    # we've found what we're
    # looking for
  }
  if (/^ISTC.*(i.\d{8})/ and ($hit == 1)) {
  # Now, if we have a match already
  # saved, look for the
  # pattern "ISTC" at
  # the beginning of the
  # line, and then anything
  # else, and then "i" followed
  # by eight digits; save the
  # "i" and the digits, as that's
  # the ISTC number
    $hit = 0;
    # Reset our flag
    $istc_number = $1;
    # Assign the "i plus eight digits"
    # to a variable
    print "$istc_number\t$match\n";
    # Print the ISTC number, a tab
    # character, the title, and a
    # new line character
  }
}

The output, as explained above (§ 6), begins like this:

ia00000500 Orhot Hayyim
ia00001000 Abbey of the Holy Ghost
ia00001500 Abbey of the Holy Ghost
ia00002000 Abbey of the Holy Ghost

This output should be redirected to a file to be saved for further use like this:

perl title.pl > title.txt

Very little needs to be changed in order to extract the rest of the fields. In the line if (/^Title:\t(.*?)$/) {, one need only replace Title with Author, Bibliography, Cataloguing Source, Collective Title, Format, Imprint, Language, Locations, or Notes.

Appendix 3: A Perl script for analyzing the IISTC imprint field

§ 19 On many occasions, it would be useful to turn the IISTC imprint field into separate fields for city, printer, and date of printing, and to clearly distinguish between signed and attributed information. The following script accomplishes this based on the output from the script in appendix 2 as applied to the Imprint field.

# This script takes as input a
# tab-delimited table of istc
# numbers and imprint fields,
# assumed here to be named 'imprint.txt'.
# This script outputs the istc number
# again as an index, followed by the
# first imprint field only, then fields
# containing the city and printer. Then
# it outputs the years: the average
# of all years in all imprint fields,
# the earliest and then the latest such
# year. The last column contains three
# flags, either + or -. Signed cities,
# printers, and dates appear as +++,
# while the opposite would be ---. Years
# appearing in single quotes ('1401')
# have been ignored.

# set imprint data file
$batch="imprint.txt";

# open the file to process, or give an error
# code
open BATCH, $batch or die "Cannot open $batch for read:$!";
# create column titles
print
"istc_number\timprint\tcity\tprinter\tavg_year\tfirst_year\tlast_year\tflags\n";
while (<BATCH>) {

  # first, reset all variables
  undef @allyears;
  undef @sort;
  $firstyear=0;
  $lastyear=0;
  $avgyear = 0;
  $yearcount = 0;
  $flags='+++';

  # save the input line as $record for later
  # use
  $record=$_;

  # get first two tab-delimited fields, the
  # ISTC Number and first imprint line
  /^(.*?)\t(.*?)\t/;
  $istc_number=$1;
  $imprint=$2;

  # search the imprint line for an optional
  # opening bracket, then the city, then a
  # colon, then the rest of the line
  $imprint=~/^(\[|)(.*?)(?:\]: |: )(.*)$/;
  $rightpart=$3;
  $city=$2;

  # if an opening bracket was found, flag
  #the city as unsigned
  if ($1) {substr $flags, 0, 1, "-"}

  # split the rest of the line by commas,
  # forming the array @printer
  @printer=split /, /, $rightpart;

  # fix 3 defective records: if there's
  # no comma found in the rest
  # of the line, and there's no number
  # to be found, add a dummy,
  # empty date element to array

  # fix defective imprint lines not
  # handled correctly: ip01005630
  # (no year,), ic00216715 (no year,), ir00334450
  if ($#printer==0 and $printer[0]!~/\d/) {push @printer, " "}


  # fix for two defective records with no
  # imprint data: print the
  # istc number and then skip the rest of the loop
  if ($record=~/^([^\t]*?)\t$/) {
    $istc_number=$1;
    print "$istc_number\n";
    next;
  }

  # remove the last element of @printer array;
  # it's usually the date field
  $date = pop @printer;

  # fix for two deficient records containing neither
  # city nor printer, just dates
  if ($imprint !~/:/) {
    $date = $imprint;
    undef @printer;
    $city = "";
  }

  # remove all brackets to test for a date; we
  # need to find the ca. 150 records of the
  # anomalous form 'City: printer, year, month
  # and day'
  $_ = $date;
  s/[\[\]]//g;
  $xdate=$_;

  # remove all brackets from current last element
  # of @printer array
  $ydate=@printer[-1];
  $ydate=~s/[\[\]]//g;

  # if $date doesn't contain a year, then check
  # the last element of @printer; if it does,
  # pop it onto the front of $date
  if ($xdate !~/1[45]\d{2}|undated/i and $ydate=~/1[45]\d{2}/) {
    $date=pop(@printer).$date;
    $_ = $date;
    s/[\[\]]//g;
    $xdate=$_;
  }

  # now obliterate dates in single quotes regarded
  # as false
  $xdate=~s/'.*?'//g;

  # match a year 1400 to 1599
  $xdate=~/(1[45]\d{2})/;

  # if we find it, use it, otherwise we have nothing
  # to test
  if ($1) {$testyear=$1} else {$testyear=""}

  # if we have a date to test, get the last two digits
  if ($testyear) {$yeardigits=substr $testyear, 2, 2} else {$yeardigits='####'}

  # if the last two digits are surrounded by brackets,
  # flag the date as unsigned. [14]94 is treated
  # as signed, 14[9]4 as unsigned
  $_ = $imprint;
  if(/\[[^\]]*$yeardigits[^\]]*\]|\[$yeardigits|$yeardigits\]/ or $yeardigits eq '####') {
    substr $flags, 2, 1, "-";
  }

  # split the input line again on the tabs
  @checkdates = split /\t/, $record;

  # but discard the first two tabs
  $null=shift @checkdates;
  $null=shift @checkdates;

  # and add the date field previously identified
  unshift (@checkdates, $date);

  # this next loop extracts all years from each
  # imprint field in turn
  foreach $possibledate (@checkdates) {
    $_=$possibledate;

    # remove brackets, get rid of '1401' dates
    s/\[|\]|'.*?'//g;

    # find simple years, like 1493, 1494-,
    # 1498-1505
    @simple_years=/(1[45]\d{2})/g;

    # add the years found to the list
    push (@allyears, @simple_years);

    # find dates like 1476-80
    $_=$possibledate;
    @complex_years=/(1[45]\d{2}[\-\/]\d{2})\D/g;

    # first count the simple years in the next loop
    foreach $simpleyear(@simple_years) {
      $avgyear+=$simpleyear;
      $yearcount++;
    }

    # and add the second part to the list of years
    # in the following loop
    foreach $complexyear (@complex_years) {

    # find the element to split on: either - or /
    $split=substr($complexyear,4,1);
    # ignoring @temp[0], as it is already a simple_year
    @temp = split /$split/, $complexyear;
    @temp[1]=substr(@temp[0],0,2).@temp[1];
    push (@allyears, @temp[1]);
    $avgyear+=@temp[1];
    $yearcount++;
    }
  }
  # round to nearest year
  if ($yearcount) {
    $avgyear=int(($avgyear/$yearcount)+.5);
  } else {
    $avgyear = "";
  }

  # now sort the years numerically
  @sort = sort { $a <=> $b } @allyears;
  $firstyear=@sort[0];
  $lastyear= @sort[-1];

  # put the printer back together
  $printer=join ', ', @printer;

  # add missing front or back brackets for aesthetics only
  $_ = $printer;
  if (/^[^\[]+\]/) {$printer='['.$printer}
  if (/\[[^\]]+$/) {$printer=$printer.']'}

  # now get rid of all brackets and store as $xprinter
  $_ = $printer;
  s/[\[\]]//g;

  # if the printer is enclosed in brackets, or begins with a
  # bracket, flag as unsigned
  $xprinter=$_;
  if ($imprint=~/\[[^\]]*\Q$xprinter\E[^\]]*/ or
  $printer=~/^\[/) {
    substr $flags, 1, 1, "-";
  }
  # output the information and continue on to the next
  # record
  print "$istc_number\t$imprint\t$city\t$xprinter\t";
  print "$avgyear\t$firstyear\t$lastyear\t$flags\n";
}

That is, the input file begins like this:

ia00000500 [Spain or Portugal: Printer of Alfasi's Halakhot, before 1492?]
ia00001000 Westminster: Wynkyn de Worde, [about 1496]
ia00001500 Westminster: Wynkyn de Worde, [about 1497]
ia00002000 Westminster: Wynkyn de Worde, [about 1500]
ia00003000 [London: John Lettou and William de Machlinia, about 1482]
ia00004000 [London]: Richard Pynson, 9 Oct. 1499
ia00004500 [London]: Richard Pynson, 9 Oct. 1499
ia00005000 [London]: Richard Pynson, '9 Oct. 1499' [about 1503]
ia00005500 [The Netherlands: Prototypography, about 1465-80]
ia00008000 Venice: Franciscus Lapicida, 20 Oct. 1494

The output of the further manipulation here appears as follows in eight different fields:

istc_number imprint city printer avg_year first_year last_year flags
ia00000500 [Spain or Portugal: Printer of Alfasi's Halakhot, before 1492?] Spain or Portugal Printer of Alfasi's Halakhot 1492 1492 1492 ---
ia00001000 Westminster: Wynkyn de Worde, [about 1496] Westminster Wynkyn de Worde 1496 1496 1496 ++-
ia00001500 Westminster: Wynkyn de Worde, [about 1497] Westminster Wynkyn de Worde 1497 1497 1497 ++-
ia00002000 Westminster: Wynkyn de Worde, [about 1500] Westminster Wynkyn de Worde 1500 1500 1500 ++-
ia00003000 [London: John Lettou and William de Machlinia, about 1482] London John Lettou and William de Machlinia 1482 1482 1482 ---
ia00004000 [London]: Richard Pynson, 9 Oct. 1499 London Richard Pynson 1499 1499 1499 -++
ia00004500 [London]: Richard Pynson, 9 Oct. 1499 London Richard Pynson 1499 1499 1499 -++
ia00005000 [London]: Richard Pynson, '9 Oct. 1499' [about 1503] London Richard Pynson 1503 1503 1503 -+-
ia00005500 [The Netherlands: Prototypography, about 1465-80] The Netherlands Prototypography 1473 1465 1480 ---
ia00008000 Venice: Franciscus Lapicida, 20 Oct. 1494 Venice Franciscus Lapicida 1494 1494 1494 +++

Appendix 4: An approach to counting incunables using the IISTC

§ 20 Turning the IISTC's Locations field into a numerical count of surviving copies presents new challenges, as the format for recording copies varies considerably between regions. American, German, and Italian libraries are always divided by semicolons; Belgian and Other libraries usually appear as City, First Library, Second Library; Dutch, Spanish, and most Other European libraries appear as City First Library, Second Library; and French and British records mix both formats. In addition, one hopes but can never be sure that the frequent records describing a library's holdings of a given incunable as (3, 1 defective) consistently mean three copies, of which one is defective rather than 3 complete copies plus one defective one. Perfect accuracy in automatically counting the IISTC's countless incunables may not be possible, but a high degree of accuracy (verified by comparing computer-generated results with old-fashioned tabulation) is achievable and sufficient for answering many questions and for helping to formulate others.

§ 21 For counting the number of extant copies in the IISTC, the process is broken down into two steps for sake of simplicity. First, a simple script-or rather, ten minor variations on a simple script-are used to extract only the relevant data from the full export of IISTC records. The following script searches out only copies in American libraries:

$batch="istc.txt"; #name of file to search
open BATCH, $batch or die "Cannot open $batch for read:$!";
while (〈BATCH〉) {
  if (/^[ ]*USA:\t(.*?)$/) {
    $match = $1;
    $hit=1;
  }
  if (/^ISTC.*(i.\d{8})/ and ($hit == 1)) {
    $hit = 0;
    $istc_number = $1;
    print "$istc_number\t$match\n";
  }
}

The output of this script is a long list of ISTC numbers and the libraries in which copies of the relevant incunable can be found:

ia00000500 JTSL (1 leaf)
ia00001000 PML
ia00002000 FolgSL; PandJG
ia00003000 AmBML; Harv(L)L; LC(L); NewL (-); PML
ia00004000 Harv(L)L; LC; PML; UPaL; YU(B)L; EHLS (sold 1981)
ia00005000 Harv(L)L; HEHL; LC(L)
ia00008000 CPhL; Harv(M)L; PML

With minor variations in the fourth line of the script, similar files can be created for the other locations by which the IISTC organizes its copy attestations: Belgium, British Isles, Other European, France, Germany, Italy/Vatican, Netherlands, Spain/Portugal, and Other. For Spain/Portugal, for example, the output begins:

ia00008000 Avila BP
ia00009200 Barcelona BCatal, BU; Córdoba BP; Madrid BN, BU; Sevilla Colombina, BU; Toledo BP; Vigo Massó; Lisboa BN
ia00012000 Avila BP
ia00014400 El Escorial RMon
ia00016500 Córdoba BCap
ia00017000 Sevilla Colombina; Coimbra BU

The list of libraries in each location that own a given incunable is useful information that can be imported as ten new fields into the database as described in appendix 1. What would also be useful, however, is if we had a count of copies in a particular location that can be easily summed to provide a worldwide incunable count (as far as the IISTC is concerned, at least). The following script provides just such a functionality for American, Italian, and German libraries. This script is invoked a bit differently than the preceding scripts, in that it expects two command-line arguments: the name of the file to be processed and the name of the file to be written. If this script were given the name count1.pl, it might be invoked as follows to read from the file usa-libraries.txt and create the file usa-count.txt:

perl count1.pl usa-libraries.txt usa-count.txt

The script is as follows:

# script to process library-output
# files for consistently
# semicolon-delimited countries: USA,
# Italy, Germany
$in=shift; # take input file from command line
$out = shift; # take output filename from command line
open IN, $in or die "Cannot open $in for read:$!";
open OUT, ">$out" or die "Cannot open $out for write:$!";
print OUT "istc_number\tlocations\tcount\n";
while (<IN>) {
  $copycount=0;
  /^(i.\d{8})\t(.*)$/;
  $istc_number=$1;
  $locations=$2;
  @libraries=split /;/, $locations;
  foreach $library (@libraries) {
    while ($library=~/\((?:\D|\d+[^,])[^\(]*?\)/) {
      $library=~s/\((?:\D|\d+[^,])[^\(]*?\)//g;
    }
  #get rid of nested parentheses
  $library=~s/\((\d{1,2})[^\(]*\)/\(\1\)/g;
  #replace (3, 1 torn) with (3)
  if ($library=~/\((\d{1,2})\)/) {$copycount+=$1} else
    {$copycount++}
  }
  print OUT "$istc_number\t$locations\t$copycount\n";
}

The output of this script includes column headings. For German libraries, for example, it begins:

istc_number locations count
ia00008000 Bamberg SB; München BSB 2
ia00009100 Gotha ForschLB; Tübingen UB 2
ia00009200 Augsburg SStB; Bamberg SB; Berlin SB; Darmstadt LHSB; Freiburg i.Br. UB; Giessen UB; Göttingen SUB; Heidelberg UB; Karlsruhe BLB; Mainz StB; München BSB (3); München UB; Passau SB; Würzburg UB (2) 17
ia00009300 Frankfurt(Main) StUB (imperfect) 1
ia00009900 Hannover KestnerM 1

The IISTC's variability in recording copies requires the script to be adapted for other locations, however. The next two scripts are minor variations on the preceding one. The first addresses locations such as Belgium that insert a comma between the name of the city and the libraries owning a particular incunable:

# script to process library-output files for
# countries delimited as City, Library1, Library2:
# Belgium, Other [usually]
$in=shift; # take input file from command line
$out = shift; # take output filename from command line
open IN, $in or die "Cannot open $in for read:$!";
open OUT, ">$out" or die "Cannot open $out for write:$!";
print OUT "istc_number\tlocations\tcount\n";
while (<IN>) {
  undef @cities;
  $copycount=0;
  /^(i.\d{8})\t(.*)$/;
  $istc_number=$1;
  $locations=$2;
  @cities=split /;/, $locations;
  foreach $city (@cities) {
    while ($city=~/\((?:\D|\d+[^,])[^\(]*?\)/) {
      $city=~s/\((?:\D|\d+[^,])[^\(]*?\)//g;
    }
  #get rid of nested parentheses
  $city=~s/\((\d{1,2})[^\(]*\)/\(\1\)/g;
  #replace (3, 1 torn) with (3)
  undef @libraries;
  if ($city =~ /,/) {
    @libraries=split /,/, $city;
    $null = shift @libraries;
  } else {$libraries[0] = $city}
  foreach $library (@libraries) {
    if ($library=~/\((\d{1,2})\)/) {
      $copycount+=$1;
    } else {$copycount++}
  }
 }
 print OUT "$istc_number\t$locations\t$copycount\n";
}

The next script is for locations such as Spain/Portugal that separate libraries within a single city from each other with commas, but without a comma after the name of the city:

# Script to process library-output files for countries
# delimited as City Library1, Library2: Other Europe,
# Spain, Netherlands, France (mostly), Britain (usually)
$in=shift; # take input file from command line
$out = shift; # take output filename from command line
open IN, $in or die "Cannot open $in for read:$!";
open OUT, ">$out" or die "Cannot open $out for write:$!";
print OUT "istc_number\tlocations\tcount\n";
while (<IN>) {
  undef @cities;
  $copycount=0;
  /^(i.\d{8})\t(.*)$/;
  $istc_number=$1;
  $locations=$2;
  @cities=split /;/, $locations;
  foreach $city (@cities) {
    while ($city=~/\((?:\D|\d+[^,])[^\(]*?\)/) {
      $city=~s/\((?:\D|\d+[^,])[^\(]*?\)//g;
    }
  #get rid of nested parentheses
  $city=~s/\((\d{1,2})[^\(]*\)/\(\1\)/g;
  #replace (3, 1 torn) with (3)
  undef @libraries;
  @libraries=split /,/, $city;
  foreach $library (@libraries) {
    if ($library=~/\((\d{1,2})\)/) {
      $copycount+=$1;
    } else {$copycount++}
  }
 }
 print OUT "$istc_number\t$locations\t$copycount\n";
}

As explained above, the IISTC contains some records that are truly ambiguous as to the number of copies in question, and for some locations the formatting is inconsistent. In the case of inconsistent formatting, some further refinement can help reduce the inaccuracies. It is undoubtedly useful for the staff of the British Library for their copies to appear at the head of the list of libraries in the British Isles rather than with other London libraries, and with signatures of all their copies; however, for attempting a count based on this data, it is distinctly annoying. Consider the following data:

ia00017000 London BL, 167.f.13 = IB.27036; Chatsworth; Edinburgh NLS (Inc.207); Oxford Bodley (2), Magdalen, Pembroke (2) Colleges; Stonyhurst College
ia00018600 Cambridge, Trinity Hall; Oxford Bodley, All Souls College
ia00020500 London BL, IC.28708; Barnard Castle, Bowes Museum
ia00021000 Cambridge, Trinity Hall; Oxford, New College

How is a computer to know that Oxford Bodley, All Souls College refers to two copies, while Oxford, New College refers to just one? The assumption that a comma divides a city and its libraries must be modified with an explicit statement that Oxford is a city, as the following script attempts to implement. As a consequence, the anomalous recording of British Library copies results in an overcount by one that must be individually corrected.

# script to process library-output files
# for British Isles.
# Remove nested parentheses first, to get
# rid of semicolons within comments, and
#then split on semicolons; if there is
# a 'London, BL', remove one from the total count
$in="libs-brit.txt"; # input file
$out = "bricount.txt"; # output file

open IN, $in or die "Cannot open $in for read:$!";
open OUT, ">$out" or die "Cannot open $out for write:$!";
print OUT "istc_number\tlocations\tcount\n"; # add column heads

while (<IN>) {
  undef @cities;
  $copycount=0;
  /^(i.\d{8})\t(.*)$/;
  $istc_number=$1;
  $locations=$2;

    # get rid of (digit) in BL signatures
    $fixlocations=$locations;
  while ($fixlocations=~/[^ ]\(\d\)/) {
    $fixlocations=~s/[^ ]\(\d\)//g;
  }

  # get rid of nested parentheses
  while ($fixlocations=~/\((?:\D|\d+[^,])[^\(]*?\)/) {
    $fixlocations=~s/\((?:\D|\d+[^,])[^\(]*?\)//g;
  }

  @cities=split /;/, $fixlocations;
  foreach $city (@cities) {
    $city=~s/\((\d{1,2})[^\(]*\)/\(\1\)/g;
    # replace (3, 1 torn) with (3)
    $city=~s/\(\d{1,2} lea[^\(]*\)//g;
    # eliminate e.g. (3 leaves)
    if ($city=~/London BL,[^,]* and /) {$copycount++}
    # correct for multiple BL signatures without
    # comma dividers
    $city=~s/(London|Oxford|Cambridge|Manchester|Dublin|Durham|Hereford|Edinburgh|Cashel|Guernsey|Coleraine|Barnard Castle|Parkminster|Northampton|Reigate| Birmingham|Canterbury|Harpenden|Brasenose|Killiney),/\1/;
     # eliminate commas after city names
    undef @libraries;
    @libraries=split /,/, $city;
    foreach $library (@libraries) {
       if ($library=~/\((\d{1,2})\)/) {
         $copycount+=$1;
       } else {
         $copycount++;
       }
       if ($library=~/London BL/) {
         $copycount--;
       }
    }
}
  print OUT "$istc_number\t$locations\t$copycount\n";
  #print "$istc_number\t$locations\t$copycount\n";
}

Some sample output illustrates that Perl can deal with a great deal of discrepancy in formatting and still arrive at a correct count, while the question of what ownership of a copy of an incunable really means is a separate issue entirely:

ia00425700 Oxford Bodley 1
ia00426000 London BL, IB.21897 (Acquisition 1985, not in BMC. Bound with Nicolaus Perottus, Rudimenta grammatices, Lyons, anonymous press (IB.21897) and Aelius Anthonius Nebrissensis, Introductiones Latinae, Logroño, Arnao de Brocar, 1510. In a Spanish binding); Oxford Bodley 2
ia00426300 Cambridge, St John's College (2 ff.) 1
ia00426500 London BL, IB.21851 1
ia00426600 London BL, Harl.5918(2) = IA.49742 (Colophon only, in the Bagford Collection) 1
ia00426700 Cambridge UL (imperfect, wants a2-7 and all after K6); Oxford Bodley (fragment consisting of ff. f1,6, quire E and ff. I2-5) 2
ia00428000 London BL, IA.20854 (Imperfect, wanting leaf g7 and sheets h4, i4) 1

---

Acknowledgements

The author wishes to thank Alvan Bregmann, Bryce Inouye, and Paul Needham for their kind assistance and helpful suggestions for this article.

Works cited

The British Library. 1998. The illustrated ISTC on CD-ROM. 2nd ed. London: Primary Source Media, in association with the British Library.

Copinger, Walter Arthur. 1895-1902. Supplement to Hain's Repertorium bibliographicum: or, collections toward a new edition of that work. London: H. Sotheran.

Davies, Martin and John Goldfinch. 1992. Vergil: a census of printed editions 1469-1500. Occasional Papers of the Bibliographical Society 7. London: The Bibliographical Society.

Gesamtkatalog der Wiegendrucke. 1925-. 10 vols. to date. Stuttgart: Hiersemann.

Hain, Ludwig. 1826-1838. Repertorium bibliographicum, in quo libri omnes ab arte typographica inventa usque ad annum MD. typis expressi, ordine alphabetico vel simpliciter enumerantur vel adcuratius recensentur. 2 vols. Stuttgart: J. G. Cotta.

Neddermeyer, Uwe. 1998. Von der Handschrift zum gedruckten Buch: Schriftlichkeit und Leseinteresse im Mittelalter und in der frühen Neuzeit. Quantitative und qualitative Aspekte. Buchwissenschaftliche Beiträge aus dem deutschen Bucharchiv München 61. 2 vols. Wiesbaden: Harrassowitz.

Needham, Paul. 1999. Counting incunables: the IISTC CD-ROM. Huntington Library Quarterly 61: 457-529.

Ohly, Kurt and Vera Sack. 1966-1967. Inkunabelkatalog der Stadt- und Universitätsbibliothek und anderer öffentlicher Sammlungen in Frankfurt am Main. Frankfurt: Klostermann.

Reichling, Dietrich. 1905-1911. Appendices ad Hainii-Copingeri Repertorium bibliographicum. 7 vols. Munich: Rosenthal.

Reske, Christoph. 2000. Die Produktion der Schedelschen Weltchronik in Nürnberg. Wiesbaden: Harrassowitz.